А еще для вас не является секретом единственно правильный сермяжный способ пересылать картинки. Что нужно сделать с JPEG, чтобы он стал всем понятен, удобен и вообще обрел православность? Правильно, запихать в документ Word. Краски на фотографии сразу становятся ярче, а краешки файла глаже и он быстрее проскальзывает в ящик адресата.

Я сегодня в этом участвовал. На вопрос — а на фига запихивать полсотни фотографий в ворд — я получил ответ — иначе они распечатать не смогут. Возразить было нечего.

Наблюдалась только одна маленькая проблемка: файл весил 130 мегабайт. Конечно, предпочтительнее было ужать четырехметровые картинки правильными инструментами, и только потом вгонять в текстовый редактор, но файл уже был готов. Спасло то, что MS Word имеет подходящую опцию.

Щелкаете правой кнопкой на картинке, выбираете Формат рисунка, потом на вкладке Рисунок нажимаете кнопку Сжать и в появившемся окне можете сжимать ваши гигапиксельные снимки далеких вселенных.

Жаль, что нельзя самостоятельно задавать разрешение, но предлагаемые 200 dpi годятся для большинства случаев. Здесь же можно удалить невидимые части рисунков — если вы кадрировали снимок с пьянки, чтобы получить свое лицо, и использовали результат в резюме на должность специалиста по безопасности, эта опция поможет запалиться хотя бы не с первой же секунды.

Что такая фишка есть, я помнил, но сегодня с огромным облегчением нашел опцию Применить ко всем рисункам документа. Два мегабайта этой бурды ушло адресату через минуту. Вместо начальных 130 мегабайт.

' strVar - значение переменной  
' strFormula - строка, содержащая саму формулу, место, куда надо
' подставить переменную, обозначено символами VAR

Function sheetFormula(strVar As String, strFormula As Variant) As Variant

' Если формула пустая, не тратим ресурсы
If strFormula = "" Then Exit Function

' Юзер - дурак, уберем крайние пробелы
strFormula = Trim(strFormula)

' Чем возиться с параметрами замены, проще все перевести
' в верхний регистр
strFormula = UCase(strFormula)

' Подставляем переменную простой заменой
strFormula = Replace(strFormula, "VAR", CStr(strVar))

' Мой (ну почему только мой?!) фирменный финт:
' заменяем запятую на точку, позволяя пользователю
' использовать любой из этих знаков
strFormula = Replace(strFormula, ",", ".")

' Вычисляем все с помощью функции Evaluate.
' Конструкция выглядит загадочно, но только так я
' добился от этой функции стабильной работы.
' Что она там себе думает, не знаю.
sheetFormula = Evaluate(CStr(strFormula) + "+0")

End Function

Теперь можно попросить пользователя в одной ячейке вбить значение переменной, в другой — формулу, а результат использовать по всей книге.

Между прочим, кого-то из вас поджидает вакансия в Проф-Медиа Business Solutions. Кого?

Также читайте всю серию постов по VBA.

Предположим, у нас есть таблица с двумя столбиками с парами взаимосвязанных параметров. Понаблюдали мы раз десять за чем там надо наблюдать, записали результаты, увидели, что зависимость линейная, и стало нам лень остальные двести измерений делать. Первый столбик мы заполним от балды, введем какой-нибудь коэффициент, а для второго значения напишем функцию.

Примерно такую:

' Очень-очень хитрая функция
' аргументы:
' myValue - значение (целое)
' coefficient - коэффициент (вещественное)
' функция возвращает значение типа variant для того,
' чтобы мы могли запихать туда сообщение об ошибке
Function Falshivka(myValue As Integer, _
coefficient As Double) As Variant
' вводим переменную для промежуточных расчетов
Dim Res As Double

' сердце и мотор функции - вычисление
Res = myValue * coefficient

' а теперь разбодяжим слишком правильный результат.
' инициализируем генератор случайных чисел
Randomize

' и используем его (функция rnd вернет случайное
' число от 0 до 1)
' таким образом мы получим некоторой разброс
' вокруг вычисленного значения
Res = Res + (Rnd - 0.5) * (Res * 0.3)

' для интереса предположим, что при исходном
' значении больше нуля, результат тоже обязан
' быть положительным и ненулевым. Проверим это
If myValue > 0 And (Res < 0 Or Res = 0) Then
' ай, не повезло! придется выводить сообщение
' об ошибке, да текстовое,
' чтобы заметно было, а потом - ручками, ручками...
Falshivka = "-= 0 =-"
Else
' все. Присваиваем функции правильный результат.
' Просто пишем имя нашей функции, знак «равно» и то,
' что она должна вернуть.
Falshivka = Res
End If
End Function

Помните, что случайные значения Rnd вовсе не случайны! Было время, я наблюдал повторяющиеся последовательности среди чисел, что она выдает.

Вот так ненавязчиво можно обмануть доверившихся вам людей. Не делайте этого! Такой примитивный и безграмотный обман быстро откроется. Зато мы создали собственную функцию, ничем не хуже встроенной. Теперь в любой ячейке можно вбить «=falshivka()», и в скобках подставить ссылки на ячейки с нужными данными.

Не палите меня, ладно?

Также читайте всю серию постов по VBA.

Иногда возникает надобность добавить одно число к куче разных ячеек, или домножить их на какой-то коэффициент.

' MultiplicateSelection
' домножает выделенные ячейки на число с округлением до десятков

Sub MultiplicateSelection()
    ' объявляем переменные
    Dim Koef As Variant, cl As Range
    ' запрашиваем у пользователя число
    Koef = InputBox("Умножить на", "Домножение выделения")
    ' если ничего не введено или нажата ОТМЕНА, выходим из процедуры
    If Koef = "" Then Exit Sub

    ' Помните о пользователе!
    ' Простейшей заменой решается проблема с десятичной точкой
    ' (в системе разделителем установлена запятая, если введена 
    ' точка, здесь она заменяется на запятую)
    Koef = Replace(Koef, ".", ",")

    ' опять перебираем выделенные ячейки
    For Each cl In Selection
        ' указываем объект, с которым будем работать
        With cl
            ' кучка возможно не нужных вам проверок и вычисление 
            If .Value <> "" And .Locked = False And _
                CStr(.Formula) = CStr(.Value) Then
                .Value = Round((.Value * CDbl(Koef)) / 10) * 10
            End If
        ' заканчиваем работу с указанным объектом
        End With
    ' закрываем цикл
    Next
' выходим из процедуры
End Sub

InputBox - обычное окошко для вводя текста пользователем. Функция возвращает пустую строку, если была нажата кнопка ОК при пустой строке ввода, или нажата Отмена.

Replace заменяет в строке одну последовательность символов на другую. Здесь используется для того, чтобы пользователю не приходилось думать о раскладке. Неважно, что он напечатает - десятичную точку или запятую, вычисления пройдут без ошибки.

Далее уже знакомый перебор выделенных ячеек.

Для чего нужна конструкция With ... End With? Если в каком-то блоке кода вы активно работаете с одним объектом, есть смысл указать его после слова With, а дальше вместо Объект.Свойство писать просто .Свойство. Это делает код более читаемым, а также, насколько я знаю, несколько ускоряет исполнение.

Я специально оставил свои проверки свойств ячейки, для интереса. В одном из моих шаблонов лист организован таким образом, что я могу выделить несколько строк целиком и запустить эту процедуру. При этом пропускаются пустые ячейки (.Value <> ""), защищенные от изменений (.Locked = False), и содержащие формулы (CStr(.Formula) = CStr(.Value)). Все остальные изменяются.

Round - округление. Поскольку округление происходит только до целых, приходится делить, а потом умножать на 10.

И еще две функции: CStr - конвертация в строку, в данном случае для корректного сравнения. CDbl - приведение к вещественному типу Double, вводит-то пользователь строку, а нам числа умножать надо. Впрочем, Visual Basic редко требует явное преобразование типов, справляется сам, но так - аккуратнее.

Специально не разбираю аргументы функций. Читайте документацию и экспериментируйте, это лучший способ понять.

Также читайте всю серию постов по VBA.

Итак, в приложения Microsoft Office встроен язык Visual Basic for Application (VBA) - близнец обычного Visual Basic (по крайней мере до 6 версии VB включительно). Его можно и нужно использовать для автоматизации рутинных операций. Все нижеизложенное относится к Excel 2003.

Вчитываться имеет смысл только если вы вообще представляете, что такое бейсик, иначе можно просто копировать текст скрипта.

Для начала скриптик, который меняет формулы в ячейках на вычисленные значения. На случай, если надо зафиксировать результат. Открывайте Excel, нажимайте Alt + F11 (или Сервис > Макрос > Редактор Visual Basic), создавайте новый модуль (Insert > Module) и поехали. Впрочем, задержитесь на секунду и дайте модулю осмысленное имя, желательно латиницей. И еще, если открыта не одна книга, посмотрите, где вы создаете модуль. Слева торчит дерево проекта (если не торчит, View > Project Explorer), там и выбирайте нужный. К сожалению, майкрософтовский офис не имеет общего хранилища для инструментов; скрипты обязательно привязываются к книге.

Теперь текст скрипта:

' FormulaToValue
' преобразует формулу в значение в выделенных ячейках

' Объявляем процедуру
Sub FormulaToValue()
' объявляем переменную cl, она будет иметь тип Range
Dim cl As Range

' перебираем все ячейки (автоматически записываемые в переменную cl)
' в выделеной пользователем части листа (Selection)
' для каждой из этих ячеек по отдельности выполняем инструкции в
' строчках между For... и Next
For Each cl In Selection
' присваиваем свойству значение (Value) каждой ячейки
' это же самое значение (смешно, да?)
cl.Value = cl.Value
Next
' выходим из процедуры
End Sub

По моему скромному, но верному мнению, комментариев достаточно. Кроме самой главной строчки.

cl.Value = cl.Value

Мы обращаемся к свойству Value объекта cl, а там лежит значение ячейки. Если ячейка вычисляемая, то все равно там содержится вычисленное значение, а формула - в свойстве Formula. Это же самое значение мы записываем обратно. При этом старое содержимое свойства Formula теряется, и ячейка сохраняет просто число (или текст, что там у вас было).

И о типе Range. Переменная такого типа является объектной, и может ссылаться на некоторый набор ячеек (или, в нашем случае, одну), которые и называется здесь объектом.

Запускать процедуру можно, выбирая ее в окошке макрос (Сервис > Макрос > Макросы... или Alt + F8). Там же можно задать горячую клавишу для каждой процедуры. А можно повесить макрос на созданную кнопку в панели инструментов. Перед запуском необходимо выделить ячейки, над которыми будет проводиться операция. Помните, что зажав Ctrl, можно выделять несмежные ячейки.

Также читайте всю серию постов по VBA.

У Microsoft не один путь. Возьмите Word. Здесь обработка подстановочных знаков по умолчанию отключена, включить ее можно, нажав Больше и отметив галку Подстановочные знаки в диалоге поиска. А если вам нужно смешивать подстановку и знаки вопроса, то экранируются они обратным слешем, вот так: «\?». Предатели писали Word.

У Microsoft не один путь, а целый лабиринт (они патентуют результаты работы генератора случайных чисел, что ли?). В Visio наоборот, чтобы символ стал знаком подстановки, его надо экранировать так: «^?». Впрочем, они могут отмазаться тем, что не успели Visio переписать, продукт-то изначально не их.

Боюсь смотреть другие программы.

И вы помните, что прежде, чем форматировать что-то напрямую, без применения стилей, надо шесть раз подумать, потом выйти на улицу и обежать вокруг фонарного столба, выкрикивая мантру «да, это действительно нужно»? Иначе щастя не будет.

Отсюда вывод: всегда, когда речь идет о целых числах (или числах с заданной точностью) используйте округление. Это формула ОКРУГЛ в русской версии Excel. Она имеет два аргумента: само число, которое требуется округлить и число разрядов. С числом разрядов просто: 2 - до сотых, 1 - до десятых, 0 - до целых, -1 - до десятков и так далее в обе стороны. Единственное исключение из этого правила - промежуточные итоги, которые будут использоваться в дальнейших расчетах. Если округлять каждый результат в цепочке вычислений, может накопиться заметная ошибка, так что округляйте с умом.